Elektro

Ovládanie krokového motora a indikácia rýchlosti otáčania

Cieľ projektu

Cieľom projektu bolo vytvoriť funkčné elektronické zapojenie, ktoré umožňuje regulovať rýchlosť otáčania krokového motora a zároveň túto rýchlosť vizuálne znázorňovať pomocou LED diód.

Hlavnou úlohou bolo prepojiť mikrokontrolér, krokový motor, jeho riadiaci obvod, potenciometer a indikačné LED diódy do jedného funkčného systému. Jednotlivé komponenty spolupracujú na základe programu vytvoreného pre mikrokontrolér Arduino.

Zoznam potrebných komponentov:

  • 1x Arduino UNO
  • 1x Driver pre krokové motory A4988
  • 1x Krokový motor NEMA 17 (42HD6021-03)
  • 1x Potenciometer 100K
  • 4x LED dióda – modrá, zelená, žltá, červená
  • 4x Rezistor 240Ω
  • 1x Kondenzátor 100μF
  • Vodiče
  • Zdroj 12V
  • USB kábel
Popis riešenia

Ako riadiaca jednotka bol použitý mikrokontrolér Arduino, ktorý zabezpečuje spracovanie vstupných signálov, riadenie krokového motora a ovládanie indikačných LED diód.

Na reguláciu rýchlosti slúži potenciometer, ktorého otáčaním sa mení vstupná analógová hodnota. Arduino túto hodnotu priebežne načítava a na jej základe určuje frekvenciu riadiacich impulzov vysielaných do ovládacieho obvodu motora.

Krokový motor je ovládaný prostredníctvom riadiaceho modulu (drivera), ktorý prijíma signály z Arduina a zabezpečuje jeho pohyb. Smer otáčania je v tomto zapojení nastavený napevno.

Na vizualizáciu rýchlosti slúžia štyri LED diódy – modrá, zelená, žltá a červená. Ich intenzita svietenia sa plynule mení v závislosti od nastavenej rýchlosti motora. Jednotlivé farby tak predstavujú rôzne úrovne rýchlosti, pričom modrá zodpovedá najnižšej a červená najvyššej úrovni.

Zdrojový kód pre Arduino:

● Arduino IDE motor_control.ino
// Driver motora
const int STEP_PIN = 3;
const int DIR_PIN = 4;

// Potenciometer
const int POT_PIN = A1;

// LED diody
const int LED_BLUE = 11;
const int LED_GREEN = 10;
const int LED_YELLOW = 9;
const int LED_RED = 6;

// Rychlost motora
const int MIN_SPEED = 100;
const int MAX_SPEED = 800;

// Potenciometer
const int POT_MIN = 40;

// Casovanie motora
unsigned long lastStepTime = 0;

void setup() {

  pinMode(STEP_PIN, OUTPUT);
  pinMode(DIR_PIN, OUTPUT);

  pinMode(LED_BLUE, OUTPUT);
  pinMode(LED_GREEN, OUTPUT);
  pinMode(LED_YELLOW, OUTPUT);
  pinMode(LED_RED, OUTPUT);

  digitalWrite(DIR_PIN, HIGH);

  vypniLED();

  Serial.begin(9600);
}

void loop() {

  // Nacitanie potenciometra
  int potValue = analogRead(POT_PIN);

  // Motor stoji pri minimalnej hodnote
  if (potValue <= POT_MIN) {
    vypniLED();
    return;
  }

  // Prevod potenciometra na rychlost
  int speedValue = map(
    potValue,
    POT_MIN,
    1023,
    MIN_SPEED,
    MAX_SPEED
  );

  speedValue = constrain(speedValue, MIN_SPEED, MAX_SPEED);

  // Interval medzi krokmi motora
  unsigned long stepInterval = 1000000UL / speedValue;

  // Generovanie krokov motora
  unsigned long currentTime = micros();

  if (currentTime - lastStepTime >= stepInterval) {

    lastStepTime = currentTime;

    digitalWrite(STEP_PIN, HIGH);
    delayMicroseconds(5);
    digitalWrite(STEP_PIN, LOW);
  }

  // Plynule riadenie LED podla rychlosti
  nastavLED(speedValue);
}

// ==========================================
// PWM LED FUNKCIE
// ==========================================

void vypniLED() {

  analogWrite(LED_BLUE, 0);
  analogWrite(LED_GREEN, 0);
  analogWrite(LED_YELLOW, 0);
  analogWrite(LED_RED, 0);
}

void nastavLED(int speedValue) {

  // Prevod rychlosti na rozsah 0-1000
  int level = map(
    speedValue,
    MIN_SPEED,
    MAX_SPEED,
    0,
    1000
  );

  level = constrain(level, 0, 1000);

  int blue = 0;
  int green = 0;
  int yellow = 0;
  int red = 0;

  // MODRA: 0 - 250
  if (level <= 250) {

    blue = map(level, 0, 250, 0, 255);
  }

  // MODRA -> ZELENA: 250 - 500
  else if (level <= 500) {

    blue = map(level, 250, 500, 255, 0);
    green = map(level, 250, 500, 0, 255);
  }

  // ZELENA -> ZLTA: 500 - 750
  else if (level <= 750) {

    green = map(level, 500, 750, 255, 0);
    yellow = map(level, 500, 750, 0, 255);
  }

  // ZLTA -> CERVENA: 750 - 1000
  else {

    yellow = map(level, 750, 1000, 255, 0);
    red = map(level, 750, 1000, 0, 255);
  }

  // Nastavenie intenzity LED
  analogWrite(LED_BLUE, blue);
  analogWrite(LED_GREEN, green);
  analogWrite(LED_YELLOW, yellow);
  analogWrite(LED_RED, red);
}
Princíp fungovania

Po pripojení napájania sa Arduino uvedie do prevádzky a začne pravidelne načítavať hodnotu z potenciometra. Tá predstavuje požadovanú rýchlosť otáčania motora.

Ak je hodnota potenciometra na minimálnej úrovni, motor zostáva zastavený a všetky LED diódy sú vypnuté.

Pri zvýšení hodnoty potenciometra Arduino prevedie načítanú hodnotu na požadovanú frekvenciu riadiacich impulzov v rozsahu 100 až 800 impulzov za sekundu. Následne začne generovať impulzy na výstupe STEP, ktoré sú odosielané do drivera motora. Každý impulz predstavuje jeden riadiaci krok motora. Zmenou frekvencie impulzov sa mení rýchlosť otáčania motora – čím vyššia je frekvencia, tým rýchlejšie sa motor otáča.

Súčasne Arduino vyhodnocuje nastavenú rýchlosť a podľa nej upravuje intenzitu svietenia jednotlivých LED diód. Na tento účel využíva metódu PWM (Pulse Width Modulation), pomocou ktorej dokáže regulovať jas LED diód.

Svetelná indikácia je rozdelená do štyroch úrovní:

Modrá LED
Pri najnižšej rýchlosti postupne zvyšuje intenzitu svietenia.
25%
Zelená LED
Pri ďalšom zvyšovaní rýchlosti postupne nahrádza modrú LED.
50%
Žltá LED
Pri vyššej rýchlosti postupne nahrádza zelenú LED.
75%
Červená LED
Pri dosiahnutí najvyšších rýchlostí postupne zvyšuje intenzitu svietenia a dosahuje maximálny jas.
100%

Prechody medzi jednotlivými farbami sú plynulé, pretože pri zmene rýchlosti sa intenzita jednej LED diódy znižuje súčasne so zvyšovaním intenzity nasledujúcej LED diódy.

Pri zmene polohy potenciometra sa tak súčasne mení rýchlosť otáčania motora aj farebná svetelná indikácia.

Schéma zapojenia projektu
Realizácia a testovanie

Elektronické zapojenie bolo zostavené na kontaktnom poli (breadboard), ktoré umožňuje jednoduché prepájanie jednotlivých komponentov bez potreby ich spájkovania.

Po zostavení zapojenia bol do mikrokontroléra Arduino nahraný zdrojový kód, ktorý zabezpečuje riadenie celého systému. Program je vytvorený tak, aby priebežne načítaval hodnotu potenciometra, podľa nej reguloval frekvenciu impulzov pre krokový motor a zároveň nastavoval intenzitu svietenia jednotlivých LED diód.

Funkčnosť projektu bola overená praktickým testovaním. Pri demonštrácii sa menila poloha potenciometra, čím dochádzalo k zmene rýchlosti otáčania krokového motora. Súčasne bolo možné pozorovať plynulú zmenu svetelnej indikácie od modrej farby až po červenú.

Testovanie potvrdilo funkčnosť regulácie rýchlosti motora aj jej vizuálnej indikácie.

Záver

Výsledkom miniprojektu je funkčný elektronický systém, ktorý umožňuje reguláciu rýchlosti krokového motora pomocou potenciometra a jej vizuálnu indikáciu prostredníctvom štyroch LED diód.

Počas realizácie projektu boli využité poznatky z oblasti elektroniky, zapájania elektrických obvodov a programovania mikrokontroléra Arduino. Projekt umožnil prakticky overiť princíp riadenia krokového motora pomocou impulzov, reguláciu intenzity LED diód pomocou PWM a vzájomnú spoluprácu hardvérových a softvérových komponentov.